Nikkei Mac 20/NIKKEI-MAC-CD-VOL-20-1998-12.ISO.7z/NIKKEI-MAC-CD-VOL-20-1998-12.ISO/デモソフトライブラリー/日本テレコムODNスターターキット/OT⁄PPP 1.0 Install/CCL Disk/Modem CCLs/TDK DN1280 (128K MP)/TDK DN1280 (128K MP)

Text File | 1997-05-28 | 3KB | 147 lines

!***************************************************************
!   Linkboy DUO128 CCL (HDLC 128Kbps MP) ver1.00
!                    Copyright 1996 株式会社ビー・ユー・ジー
!***************************************************************
@ORIGINATE
@ANSWER
!
!
!===============================================================
!    Reset Serial
!===============================================================
serreset 57600, 0, 8, 1
hsreset 0 1 0 0 0 0
!
!
!===============================================================
!    Init TA
!===============================================================
@LABEL 10
matchclr
matchstr 1 12 "OK"
settries 0
@LABEL 11
write "AT¥13"
matchread 30
inctries
iftries 3 99
jump 11
!
@LABEL 12
matchclr
matchstr 1 13 "OK"
write "AT&F !G52 E0 X2 &Q7 ¥¥q3 $S12 S172=1¥13"
matchread 30
jump 99
!
@LABEL 13
ifORIGINATE 30
!
!
!===============================================================
!    Answer
!===============================================================
@LABEL 20
matchclr
matchstr  1 61 "CONNECT 128000"
matchstr  2 62 "CONNECT 64000"
matchstr  3 63 "CONNECT 56000"
matchstr  4 64 "CONNECT 38400"
matchstr  5 65 "CONNECT 19200"
matchstr  6 66 "CONNECT 9600"
!
@LABEL 21
matchread 600
jump 21
!
!
!===============================================================
!    Originate
!===============================================================
@LABEL 30
matchclr
matchstr  1 61 "CONNECT 128000"
matchstr  2 62 "CONNECT 64000"
matchstr  3 63 "CONNECT 56000"
matchstr  4 64 "CONNECT 38400"
matchstr  5 65 "CONNECT 19200"
matchstr  6 66 "CONNECT 9600"
matchstr 11 90 "NO CARRIER"
matchstr 12 90 "ERROR"
matchstr 13 91 "NO ANSWER"
matchstr 14 92 "BUSY"
matchstr 15 92 "DELAYED"
!
note "^1に発信しています。..." 3
write "ATD^1¥13"
matchread 600
jump 99
!
!
!===============================================================
!    Connect
!===============================================================
@LABEL 60
!
@LABEL 61
note "回線速度128000 bpsで接続しています..." 2
communicatingat 128000
userhook 3
jump 69
!
@LABEL 62
note "回線速度64000 bpsで接続しています..." 2
communicatingat 64000
userhook 3
jump 69
!
@LABEL 63
note "回線速度56000 bpsで接続しています..." 2
communicatingat 56000
userhook 3
jump 69
!
@LABEL 64
note "回線速度38400 bpsで接続しています..." 2
communicatingat 38400
jump 69
!
@LABEL 65
note "回線速度19200 bpsで接続しています..." 2
communicatingat 19200
jump 69
!
@LABEL 66
note "回線速度9600 bpsで接続しています..." 2
communicatingat 9600
jump 69
!
@LABEL 69
exit 0
!
!
!===============================================================
!    Hang Up
!===============================================================
@HANGUP
DTRClear
pause 10
DTRSet
exit 0
!
!
!===============================================================
!    Error
!===============================================================
@LABEL 90
exit -6021
!
@LABEL 91
exit -6023
!
@LABEL 92
exit -6022
!
@LABEL 99
exit -6019